// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk. Don't give names to characters who don't talk.

begincreaturescript;

variables;

short i,target;
string name;
short sound = 0;

body;

beginstate INIT_STATE;
    clear_buffer();
    append_string("Talking: This ");
    append_char_name(ME);
    if (get_species(ME) > 0)
        append_string(" doesn't seem to have the ability to talk to you.");
    else append_string(" doesn't seem to want to talk to you.");
    get_buffer_text(name);
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if ((creature_type(ME) == 68) || (creature_type(ME) == 188))
	    sound = -173;
	if (creature_type(ME) == 186)
	    sound = -172;
	if (creature_type(ME) == 80)
	    sound = -161;
break;

beginstate DEAD_STATE;
    if (this_char_is_in_party())
        message_dialog("_AAAAAAAAaaaaaarrrrrrrrgh!_ Otto says before he falls to the ground, dead.", "");
    if (creature_type(ME) > 245)
        set_terrain(my_loc_x(), my_loc_y(), 508);
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE;
    if ((party_can_see_loc(my_loc_x(), my_loc_y()) && (sound != 0) && (get_ran(1, 1, 5) == 5)))
		play_sound(sound); 
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
	    create_text_bubble("Now I got you!");
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
	    create_text_bubble("You'll pay for that!");
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
	create_text_bubble("Heeyachah!");
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str(name);
		end();
		}
	if ((creature_type(ME) == 70) || (creature_type(ME) == 205)) {
	    if (get_ran(1, 1, 100) < 50)
	        play_sound(-35);
	    else play_sound(-36);
	    }
	if (sound != 0)
	    play_sound(sound);
	begin_talk_mode(get_memory_cell(3));
break;